normflt4.qry

# normflt4.qry
# This is a sample script for drawing a normal fault (dashed).
# Barbed tick marks indicating downthrown side
# of fault are drawn on the left side of the line.
# If this is the wrong side for an individual line,
# use the Spatial Data Editor to reverse its start and end points.
# Modified to provide scaling for LegendView samples, August 2002;
# Modified to declare all variables, October 2005;
# Version Dec. 2007
# Requires TNTmips 2007:73 or later.
# Modified to adjust scale based on georeference map units and to
# place a barbed tick mark only at the center of each line
numeric red, green, blue, scale;
numeric dashMap, dashSize, halfDash, tickMap, tickSize;
numeric widthMap, width, radius, lineCheck;
numeric tickDrawn;		# flag to indicate whether tick mark has been drawn yet
class RVC_GEOREFERENCE vGeoref;
class SR_COORDREFSYS vectCRS; 
###################### Set Parameters ##############################
# red, green, blue variables define the color of the line
red = 255;			green = 0;			blue = 0;
# This variable defines the denominator of the intended map scale.
# It is used as the basis for defining line width and symbol size
# and spacing.
# Example: for 1:24,000 map scale, Scale = 24000
scale = 24000;
# These variables set the length of the dashes
# DashMap is the desired dash length in mm, assuming vector
# coordinates are in meters:
dashMap = 3;
# This variable controls the length of the tick marks.
# TickMap is the desired length in mm, assuming vector
# coordinates are in meters.
tickMap = 1.5;
# These variables control the width of the line and tick marks.
# WidthMap is the desired map width in mm, assuming vector
# coordinates are in meters.
widthMap = 0.3
# Check if vector has geographic coordinates (units of degrees instead of meters) 
# and if so adjust scale factor to draw symbols of appropriate size.
Vect.GetDefaultGeoref(vGeoref);
vectCRS = vGeoref.GetCoordRefSys();
if (vectCRS.IsProjected() <> 1) {
	if (vectCRS.IsLocal() <> 1) {
		scale = scale * 0.000009;
		}
	}
else {	# CRS is projected; check coordinate units to adjust scale
	# get coordinate unit from the first axis of the planar coordinate system
	coordUnit$ = vectCRS.Coordsys.GetAxis(1).Unit.GetSymbol();
	scale = scale * GetUnitConvDist("m", coordUnit$);
	}
# set final dimensions for drawing
if (DrawingLegendView == 1) {		# set dimensions for LegendView based on sample size 
	dashSize = 0.3 * SampleRect.GetWidth();
	tickSize = 0.4 * SampleRect.GetHeight();
	width = 0.1 * SampleRect.GetHeight();
	}
else {		# set dimensions for drawing elements in View
	scale = scale / 1000;	# conversion from meters to millimeters
	dashSize = dashMap * scale;
	tickSize = tickMap * scale;
	width = widthMap * scale;
	}
halfDash = dashSize * 0.5;
# This variable controls the size of the circle at the end of
# the tick marks
radius = tickSize * 0.25;
# get length of line and set check location dashSize less than
# the midpoint; to be used to trigger placement of tick mark
lineCheck = (LineStyleGetDistanceTo(3) * 0.5) - dashSize;
######################## Process ###########################
# Set line color and width
LineStyleSetColor(red,green,blue);
LineStyleSetLineWidth(width);
# initialize flag indicating if tick mark has been drawn yet
tickDrawn = 0;
# Draw dashed fault line and tick mark with circle at end near middle
LineStyleRollPen(dashSize); # start line with dash
while (LineStyleRoll(halfDash) != 1) {	# while not at end of line roll length of half dash
	# draw tick symbol when absolute position along line (in object units)
	# passes the check location near midpoint and set flag to indicate it has been drawn
	if (LineStyleGetPosition(1) > lineCheck && tickDrawn == 0 ) {
		# Draw dash under tick symbol
		LineStyleRollPen(halfDash);
		LineStyleDropAnchor(1);
		LineStyleRollPen(halfDash);
		# Draw barbed tick mark
		LineStyleMoveToAnchor(1);
		LineStyleLineTo(90, tickSize);
		LineStyleDrawCircle(radius, 1);
		tickDrawn = 1;
		}
	else {	# draw dash along line
		LineStyleRollPen(dashSize);
		}
	}