anticln6.qry

# anticln6.qry
# This is a sample script for drawing a geological line symbol
# for an anticline (dashed, without arrows: for Japan).
# Modified to provide scaling for LegendView samples, August 2002;
# Modified to declare all variables, October 2005;
# Version Dec. 2007
# Requires TNTmips 2007:73 or later.
# Modified to adjust scale based on georeference map units and to
# put arrow symbols only at the approximate center of each line.
numeric red, green, blue, scale, dashMap, dashSize;
numeric widthMap, width, lengthMap, halfSize, lineCheck;
numeric arrowDrawn;		# flag to indicate whether arrow symbol has been drawn
class RVC_GEOREFERENCE vGeoref;
class SR_COORDREFSYS vectCRS;
###################### Set Parameters ##############################
# red, green, blue variables define the color of the line
red = 0;			green = 0;			blue = 0;
# This variable defines the denominator of the intended map scale.
# It is used as the basis for defining line width and symbol size
# and spacing.
# Example: for 1:24,000 map scale, Scale = 24000
scale = 24000;
# These variables set the length of the dashes
# DashMap is the desired dash length in mm, assuming vector
# coordinates are in meters:
dashMap = 2;
# This variable controls the width of the lines.
# WidthMap is the desired map width in mm, assuming vector
# coordinates are in meters.
widthMap = 0.3;
# This variable controls the length of the crossing lines
# LengthMap is the desired length in mm, assuming vector 
# coordinates are in meters:
lengthMap = 4;
# Check if vector has geographic coordinates (units of degrees instead of meters) 
# and if so adjust scale factor to draw symbols of appropriate size.
Vect.GetDefaultGeoref(vGeoref);
vectCRS = vGeoref.GetCoordRefSys();
if (vectCRS.IsProjected() <> 1) {
	if (vectCRS.IsLocal() <> 1) {
		scale = scale * 0.000009;
		}
	}
else {	# CRS is projected; check coordinate units to adjust scale
	# get coordinate unit from the first axis of the planar coordinate system
	coordUnit$ = vectCRS.Coordsys.GetAxis(1).Unit.GetSymbol();
	scale = scale * GetUnitConvDist("m", coordUnit$);
	}
# set final dimensions for drawing
if (DrawingLegendView == 1) {	# set dimensions for LegendView based on sample size
	dashSize = 0.3 * SampleRect.GetWidth();
	halfSize = 0.4 * SampleRect.GetHeight();
	width = 0.1 * SampleRect.GetHeight();
	}
else {	# set dimensions for drawing elements in View
	scale = scale / 1000;	# conversion from meters to millimeters
	dashSize = dashMap * scale;
	width = widthMap * scale;
	halfSize = 0.5 * lengthMap * scale;
	}
halfDash = dashSize * 0.5;
# get length of line and set check location dashSize less than
# the midpoint; to be used to trigger placement of tick mark
lineCheck = (LineStyleGetDistanceTo(3) * 0.5) - dashSize;
######################## Process ###########################
# Set line color and width
LineStyleSetColor(red,green,blue);
LineStyleSetLineWidth(width);
# initialize flag indicating if arrow symbol has been drawn yet
arrowDrawn = 0;
# Draw dashed fold line and crossing symbols
LineStyleRollPen(dashSize); # start line with dash
while (LineStyleRoll(halfDash) != 1) { # while not at end of line roll length of half dash
	# draw crossing symbol when absolute position along line (in object units)
	# passes the check location near midpoint and set flag to indicate it has been drawn
	if ( LineStyleGetPosition(1) > lineCheck && arrowDrawn == 0 ) {
		# Draw dashed line through crossing symbol
		LineStyleRollPen(halfDash);
		LineStyleDropAnchor(1);
		LineStyleRollPen(halfDash);
		# Draw crossing lines
		LineStyleMoveToAnchor(1);
		LineStyleLineTo(90, halfSize );
		LineStyleMoveToAnchor(1);
		LineStyleLineTo(-90, halfSize );
		arrowDrawn = 1;
	}
	else {
		LineStyleRollPen(dashSize)
	}
}